mirror of
https://gerrit.ovirt.org/vdsm
synced 2026-02-06 03:48:18 +01:00
96677b36c7
the PYTHON environment variable is overly useful in the configure script. AX_PYTHON_MODULE should not overwrite it while testing a specific module existence. Change-Id: I4224302b47a5f4465976af439079efd13987defa Signed-off-by: Dan Kenigsberg <danken@redhat.com> Reviewed-on: https://gerrit.ovirt.org/57301 Reviewed-by: Yaniv Bronhaim <ybronhei@redhat.com> Tested-by: Yaniv Bronhaim <ybronhei@redhat.com>
55 lines
1.5 KiB
Plaintext
55 lines
1.5 KiB
Plaintext
# ===========================================================================
|
|
# http://www.gnu.org/software/autoconf-archive/ax_python_module.html
|
|
# ===========================================================================
|
|
#
|
|
# SYNOPSIS
|
|
#
|
|
# AX_PYTHON_MODULE(modname[, fatal, python])
|
|
#
|
|
# DESCRIPTION
|
|
#
|
|
# Checks for Python module.
|
|
#
|
|
# If fatal is non-empty then absence of a module will trigger an error.
|
|
# The third parameter can either be "python" for Python 2 or "python3" for
|
|
# Python 3; defaults to Python 3.
|
|
#
|
|
# LICENSE
|
|
#
|
|
# Copyright (c) 2008 Andrew Collier
|
|
#
|
|
# Copying and distribution of this file, with or without modification, are
|
|
# permitted in any medium without royalty provided the copyright notice
|
|
# and this notice are preserved. This file is offered as-is, without any
|
|
# warranty.
|
|
|
|
#serial 8
|
|
|
|
AU_ALIAS([AC_PYTHON_MODULE], [AX_PYTHON_MODULE])
|
|
AC_DEFUN([AX_PYTHON_MODULE],[
|
|
if test -z "$3";
|
|
then
|
|
THIS_MODULE_PYTHON="python3"
|
|
else
|
|
THIS_MODULE_PYTHON="$3"
|
|
fi
|
|
|
|
PYTHON_NAME=`basename $THIS_MODULE_PYTHON`
|
|
AC_MSG_CHECKING($PYTHON_NAME module: $1)
|
|
"$THIS_MODULE_PYTHON" -c "import $1" 2>/dev/null
|
|
if test $? -eq 0;
|
|
then
|
|
AC_MSG_RESULT(yes)
|
|
eval AS_TR_CPP(HAVE_PYMOD_$1)=yes
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
eval AS_TR_CPP(HAVE_PYMOD_$1)=no
|
|
#
|
|
if test -n "$2"
|
|
then
|
|
AC_MSG_ERROR(failed to find required module $1)
|
|
exit 1
|
|
fi
|
|
fi
|
|
])
|